Subversion Repositories KardasA Overlay

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit rpm

# Revision used by upstream
SRC_REV="5"

MY_P="${P}-${SRC_REV}"

DESCRIPTION="Epson Perfection 4490 PHOTO scanner plugin for SANE 'epkowa' backend."
HOMEPAGE="http://www.avasys.jp/english/linux_e/dl_scan.html"
SRC_URI="
        x86?   ( http://linux.avasys.jp/drivers/scanner-plugins/GT-X750/${MY_P}.c2.i386.rpm )
        amd64? ( http://linux.avasys.jp/drivers/scanner-plugins/GT-X750/${MY_P}.c2.x86_64.rpm )"

LICENSE="AVASYS Public License"
SLOT="0"
KEYWORDS="~x86 ~amd64"

IUSE=""
IUSE_LINGUAS="ja"

for X in ${IUSE_LINGUAS}; do IUSE="${IUSE} linguas_${X}"; done

RESTRICT="mirror"

DEPEND=">=media-gfx/iscan-2.18.0"
RDEPEND="${DEPEND}"

src_install() {
        local MY_LIB="/usr/$(get_libdir)"

        # install scanner firmware
        insinto /usr/share/iscan
        doins "${WORKDIR}"/usr/share/iscan/*

        # install docs
        if use linguas_ja; then
           dodoc usr/share/doc/"${P}"/AVASYSPL.ja.txt
         else
           dodoc usr/share/doc/"${P}"/AVASYSPL.en.txt
        fi

        # install scanner plugins
        insinto "${MY_LIB}"/iscan
        INSOPTIONS="-m0755"
        doins "${WORKDIR}"/usr/$(get_libdir)/iscan/*
}

pkg_postinst() {
        local MY_LIB="/usr/$(get_libdir)"
        
        # Needed for scaner to work properly.
        iscan-registry --add interpreter usb 0x04b8 0x0119 ${MY_LIB}/iscan/libesint54 /usr/share/iscan/esfw54.bin
        
        elog
        elog "Firmware file esfw54.bin for Epson Perfection 4490"
        elog "PHOTO has been installed in /usr/share/iscan and"
        elog "regestered for use"
        elog
}

pkg_prerm() {
        local MY_LIB="/usr/$(get_libdir)"

        iscan-registry --remove interpreter usb 0x04b8 0x0119 ${MY_LIB}/iscan/libesint54 /usr/share/iscan/esfw54.bin
}